今天研究了一天，找到了一个完美地在封装系统过程中移除 Edge 浏览器的方法。

需要的工具：

• install_wim_tweak.exe
• MSMG Toolkit (可选)

直接教学：

先用 MSMG Toolkit 挂载 wim 镜像（如果你不喜欢这个可以使用别的工具挂载）。挂载后打开提升权限了的 cmd。

install_wim_tweak.exe /c Microsoft-Windows-Internet-Browser-Package /r

然后输入你的挂载路径，等待脚本运行完毕后，使用 MSMG Toolkit 的移除功能移除 Edge 即可（新版和旧版都要移除）。

如果你不喜欢 MSMG Toolkit ，这里提供另一个方案：

@echo off
set "Mount=D:\\Mount"

call :WORK 2>nul
pause
exit /b

:WORK
if not exist "%Mount%\\Windows\\explorer.exe" exit /b
reg query "HKU\\S-1-5-19" >nul 2>nul || exit /b
set "E1=x86\_microsoft-windows-edgechromium\_31bf3856ad364e35\_10.0.19041.3636\_none\_181897eb58d04a07"
set "E2=x86\_microsoft-windows-edgechromium\_31bf3856ad364e35\_none\_83204c2f0ca4ce9b"
if exist "%Mount%\\Windows\\SysWOW64" (
    set "E1=amd64\_microsoft-windows-edgechromium\_31bf3856ad364e35\_10.0.19041.3636\_none\_7437336f112dbb3d"
    set "E2=amd64\_microsoft-windows-edgechromium\_31bf3856ad364e35\_none\_df3ee7b2c5023fd1"
)
set "F1=%Mount%\\Windows\\WinSxS\\%E1%"
set "F2=%Mount%\\Windows\\WinSxS\\Manifests\\%E1%.manifest"
if exist "%Mount%\\Program Files (x86)\\Microsoft\\Edge\*" rd /s /q "%Mount%\\Program Files (x86)\\Microsoft"
if exist "%Mount%\\Program Files\\Microsoft\\Edge\*" rd /s /q "%Mount%\\Program Files\\Microsoft"
takeown /F "%F1%" && cacls "%F1%" /E /G %USERNAME%:F && rd /s /q "%F1%"
takeown /F "%F2%" && cacls "%F2%" /E /G %USERNAME%:F && del /f /q "%F2%"
reg load HKLM\\TK\_COMPONENTS "%Mount%\\Windows\\System32\\config\\COMPONENTS"
reg load HKLM\\TK\_SOFTWARE "%Mount%\\Windows\\System32\\config\\SOFTWARE"
reg load HKLM\\TK\_SYSTEM "%Mount%\\Windows\\System32\\config\\SYSTEM"
reg delete "HKLM\\TK\_COMPONENTS\\DerivedData\\Components\\%E1%" /f
reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\SideBySide\\Winners\\%E2%" /f
reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Active Setup\\Installed Components\\{9459C573-B17A-45AE-9F64-1857B5D58CEE}" /f
reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Image File Execution Options\\MicrosoftEdgeUpdate.exe" /f
reg delete "HKLM\\TK\_SYSTEM\\ControlSet001\\Services\\edgeupdate" /f
reg delete "HKLM\\TK\_SYSTEM\\ControlSet001\\Services\\edgeupdatem" /f
if exist "%Mount%\\Windows\\SysWOW64" (
    reg delete "HKLM\\TK\_SOFTWARE\\WOW6432Node\\Microsoft\\EdgeUpdate" /f
    reg delete "HKLM\\TK\_SOFTWARE\\WOW6432Node\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft Edge" /f
    reg delete "HKLM\\TK\_SOFTWARE\\WOW6432Node\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft Edge Update" /f
    @REM reg delete "HKLM\\TK\_SOFTWARE\\WOW6432Node\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft EdgeWebView" /f
) else (
    reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\EdgeUpdate" /f
    reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft Edge" /f
    reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft Edge Update" /f
    @REM reg delete "HKLM\\TK\_SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Microsoft EdgeWebView" /f
)
reg unload HKLM\\TK\_COMPONENTS
reg unload HKLM\\TK\_SOFTWARE
reg unload HKLM\\TK\_SYSTEM
goto :eof

本方法无任何图标残留。